Sat 08 Feb 20 @ 3:39 am

my uid 7697545
param_equal `get_loaded_song 'alreadyplayed'` 'yes' ? on : off
Test if several things are true with just one question mark

set 'a' 1 & set 'b' 2 & set 'c' 3 & param_equal "`var 'a' 1 && var 'b' 2 && var 'c' 3`" 1 ? set 'result' 1 : set 'result' 0

between 2 values one question mark
param_equal "`param_smaller 'effect_slider echo 1' 0.1`" "`param_bigger 'effect_slider echo 1' 0.2`" ? [in between 0.1 & 0.2] : [not inbetween]

Increment vars

set 'a' +1

cast then query for things that aren't straight forward

set 'a' 2 & get_var 'a' & param_cast 'integer' & has_cue & param_equal 1 ? [cue 2 exists] : [it doesn't]

inverted queries

set 'a' 1 & set 'b' 1 & var_equal 'a' 'b' !? [not equal] : [equal]

Dynamic variable names

set '$myvar' 4 & param_add `get_var '$myvar' & param_cast 'text'` `get_text '$mynewvar'` & param_cast 'text' & toggle

result toggle $mynewvar4

Append a tag with ' ABC'

param_add `get_text ' ABC'` `get_browsed_song 'comment'` & param_cast 'text' & browsed_song 'comment'

get_browsed_song 'comment' & param_add ' ABC' & param_cast 'text' & browsed_song 'comment'
Append a tag with ' ABC' ' 123'

PARAM_ADD "GET_TEXT ' 123'" "param_add `get_text ' ABC'` `get_browsed_song 'comment'`" & param_cast 'text' & browsed_song 'comment'


get_slip_time return beats from current.

`param_add "get_time elapsed 1000 & param_multiply -1" "get_slip_time" & param_multiply "param_multiply get_bpm 'get_constant 60000 & param_1_x'"`


loop roll stutters

http://www.virtualdj.com/forums/241779/VirtualDJ_Technical_Support/Slider_Filter_on_Pad.html?search=I%20call%20this%20one%20fun&page=1.7


1 hour countdown
set 'test' 3600 & set 'clock' `get_clock` & repeat_start_instant 'ticktock' 50ms -1 & param_equal `get_var clock` `get_clock` ? : cycle test -3600 & set 'clock' `get_clock` & set sec `param_mod 60 "get_var test" & param_cast '00'` & set min `param_multiply 0.0166666666666 "get_var 'test'"` & set min `get_var min & param_cast 'int_trunc' & param_cast '00'` & set_var counter `param_add "get_text ':'" "get_var 'min'"` & set_var 'counter' `param_add "get_var 'sec'" "get_var 'counter'"` & get_var 'counter' & param_cast 'text' & deck master effect_string 'text' 2

exit cue

goto 100% & set 'myVar' `param_mod 16 "get_beatpos" & param_multiply -1` & get_var 'myVar' & param_cast 'relative' & goto & goto -32 & get_beatpos & param_cast & set_cue 8 & cue_name 8 "Outro 8B"

key to filter folder
set_var folderString ".vdjfolder" &
set folderString `param_add 'get_var folderString' 'get_harmonic'` &
set folderString `param_add 'get_var folderString' 'get_text "C:\Users\user\Documents\VirtualDJ\Folders\Filters\Keys.subfolders\"'` &
browser_gotofolder `get_var folderString

Scrolling

repeat_start_instant scroller ? on & repeat_stop scroller : off & browser_window songs & browser_scroll top & repeat_start_instant scroller 50ms -1 &
THE THING &
browser_scroll bottom ? repeat_stop scroller : browser_scroll +1


volume & samples

set $volManip 0 & deck master repeat_start volManip 25ms -1 & var $volManip 0 ? param_smaller 0.5 `deck 1 level` ? sampler_play 1 & set $volManip 1 : deck all level -2% : var $volManip 1 ? sampler_used ? : set $volManip 2 : var $volManip 2 ? param_equal 1.0 `deck 1 level` ? deck master repeat_stop volManip & set $volManip 0 : deck all level +2%

or

sampler_play FILEPATH & set $volManip 0 & deck master repeat_start volManip 25ms -1 & var $volManip 0 ? action_deck 1 ? param_smaller 0.5 `deck 1 level` ? set $volManip 1 : deck 1 level -2% : param_smaller 0.5 `deck 2 level` ? set $volManip 1 : deck 2 level -2% : var $volManip 1 ? sampler_used ? : set $volManip 2 : var $volManip 2 ? action_deck 1 ? param_equal 1.0 `deck 1 level` ? deck master repeat_stop volManip & set $volManip 0 : deck 1 level +2% : param_equal 1.0 `deck 2 level` ? deck master repeat_stop volManip & set $volManip 0 : deck 2 level +2%

or

sampler_play FILEPATH & set $volManip 0 & deck master repeat_start volManip 25ms -1 & var $volManip 0 ? param_smaller 0.5 `deck active level` ? set $volManip 1 : deck active level -2% : var $volManip 1 ? sampler_used ? : set $volManip 2 : var $volManip 2 ? param_equal 1.0 `deck active level` ? deck master repeat_stop volManip & set $volManip 0 : deck active level +2%